SeyrüseferSeyir DefteriMühendislik → Takviyesiz Konik Kabukların Doğrusal Burkulması

Takviyesiz Konik Kabukların Doğrusal Burkulması

Seyir Defteri - Mühendislik
Perşembe, 08 Kasım 2018

Koni Burkulması - CCXİnce cidarlı konik kabuklar mühendisliğin bâzı alanlarında sıklıkla kullanılır ki denizcilik ve havacılık bu uygulama sahalarından en önde gelenleridir. Bu tür bir yapının tasarımında dikkât edilmesi gereken öncelikli husus, yük altındaki kabuğun yapısal kararlığını sürdürebilme yeteneğini doğru olarak tespit edebilmektir.

Burada sadece denizcilik uygulamalarına ve bu alan içinden de temel olarak sualtı uygulamalarına odaklanılacağı için muhtelif yükleme seçenekleri arasından ağırlıklı olarak hidrostatik basınç altındaki davranışları ele alınacaktır. Konik yapılar hakkındaki kısa değerlendirme toplam üç safhadan meydana gelecektir:

Bu ilk bölümde ince cidarlı takviyesiz konik kabuklar, ikinci bölümde ince cidarlı takviyeli konik kabuklar sadece doğrusal burkulma açısından değerlendirildikten sonra eğer yetişirse, son bölümde her ikisinin doğrusal-olmayan burkulma davranışlarının değerlendirilecektir.


Tip209 sınıfı denizaltılar üzerinde konik yapılar

Resim.1) Tip209-1.400 sınıfı denizaltıların mukavim tekneleri üzerinde kullanılan konik yapılar.
Kıçta düz kubbe ile sonlanan birden fazla simetrik konik yapı mevcut.
Başta ise yaklaşık 1,25D'lik bir sığ-küre kubbe ile nihayetlenen, dike yakın bir asimetrik koni tercih edilmiş.


Aslına bakılırsa sualtı uygulamaları açısından büyük ölçüde takviyeli konik kabuklar [Resim.1] kullanılır fakat konuya daha temelden bir giriş yapabilmek için takviyesiz konilerle başlamak daha mantıklıydı. Bu doğrultuda denel çalışmalara ait veriler çok önemli olduğundan kaynak [3] başlangıç noktası olarak seçildi ve burada deneyler için imâl edilen geometri temel alındı.


Çalışmada kullanılan, gmsh ile üretilen geometriler

Resim.2) Çalışmada kullanılan, Gmsh ile üretilen geometriler.


Söz konusu geometriyi ve sonlu elemanlar çözümleri için ihtiyaç duyulan hesaplama örgüsünü oluşturabilmek amacıyla açık-kaynak Gmsh [1] yazılımı kullanıldı. Böylece aşağıda verilen betik vasıtasıyla burada kullanılan önişlem malzemelerini konuyla ilgilenenlerin kolayca elde edebilmesi de mümkün hâle geldi.


♦ gmsh:
  1. // Takviyesiz İnce Cidarlı Koni Burkulma Doğrulama Çalışması İçin
  2. // Kaynak: Collapse and Buckling of Conical Shells, 2011
  3. // J. Blachut - O. Ifayefunmi - M. Corfa
  4. // Esneklik Katsayısı= 210,49GPa / Poisson Oranı= 0,281 / kalınlık= 0,002m
  5. // Üsküdar Mühendishanesi - http://uskudar.biz
  6. // Temel veriler
  7. r1 = 0.074; // küçük yarıçap, m
  8. r2 = 0.099; // büyük yarıçap, m
  9. h0 = 0.100; // yükselik, m
  10. a0 = 0; // eksen açısı, derece. 0 simetrik, (bu durum için) 14 dik koni
  11. d0 = 36; // çeyrek daire için düğüm sayısı
  12. d1 = 26; // uzunluk yönünde düğüm sayısı
  13. // Eksen açısı için
  14. z1 = h0*(Tan(a0*Pi/180));
  15. // Noktalar
  16. Point(1) = {0, 0, 0}; // merkez 1
  17. Point(2) = {h0, 0, z1}; // merkez 2
  18. Point(3) = {0, r2, 0};
  19. Point(4) = {h0, r1, z1};
  20. Point(5) = {0, 0, r2};
  21. Point(6) = {h0, 0, r1+z1};
  22. Point(7) = {0, -r2, 0};
  23. Point(8) = {h0, -r1, z1};
  24. Point(9) = {0, 0, -r2};
  25. Point(10) = {h0, 0, -r1+z1};
  26. // Çizgiler
  27. Circle(1) = {5,1,3};
  28. Circle(2) = {3,1,9};
  29. Circle(3) = {9,1,7};
  30. Circle(4) = {7,1,5};
  31. Circle(5) = {6,2,4};
  32. Circle(6) = {4,2,10};
  33. Circle(7) = {10,2,8};
  34. Circle(8) = {8,2,6};
  35. Line(9) = {3,4};
  36. Line(10) = {9,10};
  37. Line(11) = {7,8};
  38. Line(12) = {5,6};
  39. // Yüzeyler
  40. Line Loop(1) = {1,9,-5,-12};
  41. Surface(1) = {1};
  42. Line Loop(2) = {2,10,-6,-9};
  43. Surface(2) = {2};
  44. Line Loop(3) = {3,11,-7,-10};
  45. Surface(3) = {3};
  46. Line Loop(4) = {4,12,-8,-11};
  47. Surface(4) = {4};
  48. Transfinite Line {1,2,3,4,5,6,7,8} = d0;
  49. Transfinite Line {9,10,11,12} = d1;
  50. Transfinite Surface "*";
  51. Recombine Surface "*";
  52. // Örgü yüzey normallerini ters çevirmek için
  53. // Burada kullanmak şart değildi ama ihtiyaç halinde faydalı olur...
  54. Reverse Surface {1,2,3,4} ;
  55. // CalculiX için gerekli bâzı ayarlar
  56. Mesh.SecondOrderIncomplete=1; // 2.derece elemanları doğru ihraç etmek için gerekli
  57. Mesh.SaveGroupsOfNodes = 1; // düğüm gruplarının kaydedilmesi için
  58. Mesh.ElementOrder = 2; // ikinci derece elemanlar için 2
  59. // CalculiX için adlandırmalar
  60. Physical Line("mesnet") = {1,2,3,4};
  61. Physical Line("yuk") = {5,6,7,8};
  62. Physical Surface("cidar") = {1,2,3,4};


Mevcut ayarlar ile bu betik 3.890 dörtgen hücreden meydana gelen ikinci derece bir düzenli örgü oluşturmaktadır ve eğer *.inp olarak ihraç edilirse, burada uygulandığı gibi, CalCuliX [2] ile doğrusal burkulma hesaplarını gerçekleştirmek için de kullanılabilir.

[3] içindeki denel ve hesaplamalı sonuçlarla karşılaştırma amacıyla orada tanımlanan 14° simetrik koni geometrisine eşdeğer bir yapı oluşturulmuş olmakla birlikte içerik biraz daha genişletildi.

[Resim.1] üzerinde görüldüğü gibi denizaltı mukavim tekneleri üzerinde bazen asimetrik koniler de kullanılabilmektedir. Bu sebeple verilen Gmsh betiği üzerine, simetrik koniye ilave olarak asimetrik koni oluşturma imkânı da ilave edildi.

Böylelikle [3] üzerinde kullanılan simetrik koniye (a0=0°) ilave olarak, 3°, 6°, 10° ve 14° (dik koni) olarak dört farklı asimetrik konik kabuk daha oluşturularak [Resim.2] doğrusal burkulma davranışları incelendi. CalCuliX 2.14 ile elde edilen sonuçların özetleri aşağıda görülebilir...


Calculix ile hesaplanan doğrusal burkulma sonuçlarının özeti

Resim.3) 1e06Pa hidrostatik basınç altında CalCuliX-2.14 ile hesaplanan doğrusal burkulma katsayılarının ilk beş moda ait sonuçları. Gerçek burkulma sonuçlarının doğrusal yaklaşımla elde edilen değerlerin kabaca dörtte biri mertebesinde olacağını da dikkâte almak uygun olur.


0derece 3derece 6derece 10derece 14derece
MPa % % % %
mod.1 19,26 -1,2 -3,3 -6,7 -10,8
mod.2 19,63 -3,0 -5,1 -8,4 -12,5
mod.3 19,63 0,9 2,3 4,0 5,0
mod.4 21,08 -6,0 -4,7 -2,7 -0,3
mod.5 24,04 -12,1 -11,5 -10,0 -8,0

Çizelge.1) Simetrik koni için hesaplanan hidrostatik burkulma sonuçlarının farklı eksen açılarına ait çözümlerle arasındaki farklar.
Görüldüğü gibi ilk mod için dik koni simetrik koniye göre %10,8 daha az yük taşıyabiliyor, en azından doğrusal açıdan...


Simetrik ve Dik Koni için Calculix CCX ile hesaplanan 1. burkulma modları

Resim.4) Simetrik (0derece) ve Dik (14derece) Koni için Calculix CCX ile hesaplanan 1. burkulma modları.
Sayısal değerler [Resim.3] üzerinde görülebilir.


♦ Kaynaklar

1. Gmsh genelağ sitesi - http://gmsh.info
2. Calculix genelağ sitesi - http://calculix.de
3. Collapse and Buckling of Conical Shells, 2011, J. Blachut - O. Ifayefunmi - M. Corfa
 







Telif Hakkı © 1997-2018 [uskudar.biz] - sürüm 5.5.1 - Bütün Hakları Saklıdır. Kullanım şartları için tıklayın!
Joomla! GNU/GPL lisansı altında özgür bir yazılımdır.